Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00032_DragSprite.ls

Text File | 2004-07-11 | 5.4 KB | 208 lines

--
-- DragSprite
--

property ancestor

-- constants:
property dragTopSpriteColor  -- the spriteColor of the dragging sprite - for setup
property dragUnderSpriteColor
property dragTopField
property hiliteInk  -- the hilite ink color for the project

property dragTopSprite  -- the spriteNumber of the dragging sprite
property dragUnderSprite  -- the sprite that drags under the cursor to find intersecting sprites.
property hiliteSprite  -- the sprite that will do the rollover hiliting

property hiliteList  -- a list of hilitable sprites.  They hilite when the dragger is over them.
property inkList  -- a prop list of sprite ink colors, by sprite number.
property void  -- never initialize this.

property underCast


on new me
  -- set constants:
  set dragTopSpriteColor = 5  -- red
  set dragUnderSpriteColor = 4  -- pink
  set dragTopField = "dragTopField"
  set hiliteInk = 4

  -- initialize the ancestor:
  set ancestor = new (script "MemberAnimation")

  -- do other initializations:
  setUp (me)

  set underCast = the number of member "underCursor"

  set hiliteList = []
  set inkList = []
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


on dragSprite me, spr
  set originalLoc = the loc of sprite spr
  set sprOffSet = originalLoc - the clickLoc  -- get offset information immediately

  puppetSprite spr, TRUE

  if dragTopSprite then
    set the memberNum of sprite dragTopSprite to the memberNum of sprite spr
    set the castLibNum of sprite dragTopSprite to the castLibNum of sprite spr
    set the loc of sprite dragTopSprite to the loc of sprite spr
  end if

  moveOffScreen (me, spr)

  if dragUnderSprite then
    puppetSprite dragUnderSprite, TRUE
    --    set the member of sprite dragUnderSprite to member "underCursor"  -- too slow...?
    set the castNum of sprite dragUnderSprite to underCast
  end if

  doDrag (me, spr, sprOffSet) -- do the actual dragging.

  if dragTopSprite then set tmpLoc = the loc of sprite dragTopSprite

  -- this was to return the location of the drag under sprite, currently we return the sprite number itself.
  --  if dragUnderSprite then set endLoc = the loc of sprite dragUnderSprite
  --  else set endLoc = void

  if dragTopSprite then moveOffScreen (me, dragTopSprite)

  if dragTopSprite then inkOff (me, hiliteSprite)

  set the loc of sprite spr to tmpLoc  -- move original spr back onscreen.

  unloadCast (me)

  updateStage

  if dragUnderSprite then return dragUnderSprite
  else if the loc of sprite spr = originalLoc then return -1
  else return void
end


-- drag the passed sprite, hiliting with inks.

on doDrag me, spr, sprOffSet
  -- cursor [the number of member "hand", the number of member "hand mask"]
  -- set tmp = []
  --  if dragTopSprite then add (tmp, dragTopSprite)
  --  if dragUnderSprite then add (tmp, dragUnderSprite)
  --  initHandCursor ("hand", tmp)
  repeat while the mouseDown
    set m = mouseLoc(me)
    if dragTopSprite then set the loc of sprite dragTopSprite to (m + sprOffSet)
    if dragUnderSprite then set the loc of sprite dragUnderSprite to m
    -- updateStage -- will this speed things up?
    -- check for rollovers in the hilite list and
    -- do a hilite or take it away:
    checkHiliteInk (me)
    updateStage
  end repeat
  -- cursor 0
end


-- restore the ink of a draggable to matte:

on inkOff me, spr
  if the ink of sprite spr = hiliteInk then
    moveOffScreen (me, spr)
    set the ink of sprite spr to 8  -- was this unecessary...?
  end if
end


--finally ditch the dragUnderSprite:

on hideUnderSprite me
  if not dragUnderSprite then return
  moveOffScreen (me, dragUnderSprite)
end


-- check the ink of the sprites under the cursor:

on checkHiliteInk me
  if not dragUnderSprite then return
  if not hiliteSprite then return

  moveOffScreen (me, hiliteSprite)

  set c = count (hiliteList)
  repeat with i = c down to 1
    set spr = getAt (hiliteList, i)

    if sprite dragUnderSprite intersects spr then
      set the member of sprite hiliteSprite to member the memberNum of sprite spr of castLib the castLibNum of sprite spr
      --set the castLib of sprite hiliteSprite to castLib the castLibNum of sprite spr
      set the loc of sprite hiliteSprite to the loc of sprite spr
      set the ink of sprite hiliteSprite to hiliteInk
      exit repeat
    end if
  end repeat
end


-- manually change the hiliteInk

on setHiliteInk me, num
  set hiliteInk = num
end


on setUp me, hilites
  set dragUnderSprite = 0
  set dragTopSprite = 0

  repeat with i = 1 to numSprites (me)
    if the scoreColor of sprite i = dragTopSpriteColor then
      set dragTopSprite = i
      exit repeat
    end if
  end repeat

  repeat with i = 1 to numSprites (me)
    if the scoreColor of sprite i = dragUnderSpriteColor then
      if hiliteSprite then set dragUnderSprite = i
      else set hiliteSprite = i
    end if
  end repeat

  -- makeField (me, dragTopField, dragTopSprite)
end


-- hilites must be a list of sprite numbers.

on initHilitePool me, hilites
  if listP (hilites) then set hiliteList = hilites
  setInkList (me)
end



-- set the ink list for any sprites passed in the hiliteList.

on setInkList me
  if not listP (hiliteList) then
    put "Hilite List (in DragSprite) was not initialized."
    return
  end if

  set inkList = [:]
  repeat with spr in hiliteList
    if integerP (spr) then addProp (inkList, spr, the ink of sprite spr)
  end repeat
end